home *** CD-ROM | disk | FTP | other *** search
/ Gekkan Dennou Club 140 / Gekkan Dennou Club - 2000.1 Vol. 140 (Japan).7z / Gekkan Dennou Club - 2000.1 Vol. 140 (Japan) (Track 1).bin / tools / xpicw / xpicw110.lzh / WLSource / up2.s < prev    next >
Text File  |  1997-04-10  |  2KB  |  144 lines
  1. *    up2.s
  2. *        上スクロールその２ / 最高速 = 5
  3. *            by Mitsuky
  4.  
  5.  
  6. SPEED_MAX    equ    5
  7.  
  8.     .offset    8        * 引き数
  9. _source_ptr:    .ds.l    1
  10. _dest_ptr:    .ds.l    1
  11. _speed:        .ds.l    1
  12. _vdisp:        .ds.l    1
  13.  
  14.  
  15.  
  16. TRANS32    .macro    num        * 32 バイト転送マクロ
  17.     movem.l    num(a3),d0-d3/a0-a2/a5
  18.     movem.l    d0-d3/a0-a2/a5,-(a4)
  19.     .endm
  20.  
  21.  
  22.     .text
  23.     .even
  24.  
  25.     .dc.b    'WL10',$0d,$0a
  26.     .dc.b    '上スクロールその２ / 最高速 = 5',$0d,$0a
  27.     .dc.b    '    by Mitsuky',$0d,$0a
  28.     .dc.b    $1a
  29.     .even
  30.  
  31. up2:
  32.     link    a6,#0
  33.     movem.l    d1-d7/a0-a5,-(sp)
  34.  
  35.     move.l    _speed(a6),d0    * d0.w =
  36.     bmi    up2_ask_speed
  37.     cmpi.l    #SPEED_MAX,d0
  38.     bhi    up2_err
  39.  
  40.     tst.l    _vdisp(a6)
  41.     bmi    up2_ask_vdisp
  42.  
  43.  
  44.  
  45.     moveq.l    #1,d5
  46.     lsl.w    d0,d5
  47.     move.l    #512,d7
  48.     sub.w    d5,d7        * d7.l = スクロール座標
  49.     subq.w    #1,d5        * d5.w = V-SYNC 当たりのループ回数－１
  50.  
  51.     move.w    #512,d6
  52.     lsr.w    d0,d6
  53.     subq.w    #1,d6        * d6.w = ループ回数－１
  54.  
  55.     movea.l    _source_ptr(a6),a3
  56.     movea.l    _dest_ptr(a6),a4
  57.     adda.l    #512*512*2-32,a3    * a3.l = 転送元アドレス
  58.     adda.l    #512*512*2,a4        * a4.l = 転送先アドレス
  59.  
  60.  
  61. loop:
  62.     bsr    vdisp
  63.  
  64.     move.w    d5,d4        * d5.w =
  65. loop_y2:
  66.     TRANS32    0        * HAS ver3.x なら 0(a3) は (a3) に最適化される
  67.     TRANS32    -32*1
  68.     TRANS32    -32*2        * 上スクロールは速度的に一番厳しいので
  69.     TRANS32    -32*3        * ループ展開
  70.     TRANS32    -32*4
  71.     TRANS32    -32*5
  72.     TRANS32    -32*6
  73.     TRANS32    -32*7
  74.     TRANS32    -32*8
  75.     TRANS32    -32*9
  76.     TRANS32    -32*10
  77.     TRANS32    -32*11
  78.     TRANS32    -32*12
  79.     TRANS32    -32*13
  80.     TRANS32    -32*14
  81.     TRANS32    -32*15
  82.     TRANS32    -32*16
  83.     TRANS32    -32*17
  84.     TRANS32    -32*18
  85.     TRANS32    -32*19
  86.     TRANS32    -32*20
  87.     TRANS32    -32*21
  88.     TRANS32    -32*22
  89.     TRANS32    -32*23
  90.     TRANS32    -32*24
  91.     TRANS32    -32*25
  92.     TRANS32    -32*26
  93.     TRANS32    -32*27
  94.     TRANS32    -32*28
  95.     TRANS32    -32*29
  96.     TRANS32    -32*30
  97.     TRANS32    -32*31
  98.  
  99.     subq.w    #1,d7
  100.     lea.l    -1024(a3),a3
  101.     dbra    d4,loop_y2
  102.     dbra    d6,loop
  103.  
  104.  
  105. up2_rts:
  106.     moveq.l    #0,d0
  107. up2_rts_2:
  108.     movem.l    (sp)+,d1-d7/a0-a5
  109.     unlk    a6
  110.     rts
  111.  
  112.  
  113. ****    ****
  114. vdisp:
  115.     movem.l    a0,-(sp)
  116.     move.l    _vdisp(a6),a0
  117.     jsr    (a0)
  118.     movem.l    (sp)+,a0
  119.     rts
  120.  
  121.  
  122. ****    ****
  123. up2_err:
  124.     moveq.l    #-1,d0
  125.     bra    up2_rts_2
  126.  
  127.  
  128. ****    ****
  129. up2_ask_speed:
  130.     moveq.l    #SPEED_MAX,d0
  131.     bra    up2_rts_2
  132.  
  133.  
  134. ****    ****
  135. up2_ask_vdisp:
  136.     move.l    _speed(a6),d0
  137.     lea.l    ask_vdisp_table(pc),a0
  138.     add.w    d0,d0
  139.     move.w    (a0,d0.w),d0
  140.     bra    up2_rts_2
  141.  
  142. ask_vdisp_table:
  143.     .dc.w    512,256,128,64,32,16
  144.